home *** CD-ROM | disk | FTP | other *** search
/ Atari Forever 4 / Atari Forever 4.zip / Atari Forever 4.iso / FALCON / DEMOSRGB / FD_RGB06 / U_TRACK / EXEMPLE / N_COOKIE.S next >
Text File  |  1998-03-14  |  4KB  |  153 lines
  1. ; 
  2. ; gestion du cookie jar 2.0 (1991 by TBC)
  3. ;
  4.  
  5.     .export    get_cookie
  6.     .export    add_cookie
  7.     .export    remove_cookie
  8.     
  9. ; ------------------------------------------------------------------
  10. ; récupére un cookie
  11. ; entrée : d0 = identificateur
  12. ; sortie : a0 = pointeur sur structure cookie
  13. ; ------------------------------------------------------------------
  14.  
  15.     text
  16.  
  17. get_cookie:
  18.     movem.l    d1-d7/a1-a6,-(a7)
  19.     move.l    d0,param
  20.     pea        rout_get(pc)
  21.     move.w    #$26,-(a7)
  22.     trap    #14
  23.     addq.l    #6,a7
  24.     move.l    pt_cook,a0
  25.     movem.l    (a7)+,d1-d7/a1-a6
  26.     rts
  27.     
  28. rout_get:
  29.     move.l    #0,pt_cook            ; par défaut retourne NULL
  30.     move.l    param,d0            ; d0 = parametre
  31.     move.l    $5a0.w,a0            ; a0 = adresse jar
  32.     cmp.l    #0,a0                ; inexistante ?
  33.     beq.b    fin_get                ; oui -> sort
  34.     
  35. bcl_get:
  36.     move.l    (a0),d1                ; d1 = id cookie
  37.     beq.b    fin_get                ; = 0 (fini) -> sort
  38.     cmp.l    d0,d1                ; compare avec recherché
  39.     beq.b    ok_cookie            ; idem -> ok
  40.     addq.l    #8,a0                ; different passe au suivant
  41.     bra.b    bcl_get                ; et boucle
  42.     
  43. ok_cookie:
  44.     move.l    a0,pt_cook            ; sauve adresse
  45.  
  46. fin_get:
  47.     rts                            ; retour
  48.  
  49. * ------------------------------------------------------------------------
  50. * ajoute un cookie
  51. * entrée : a0 = pointeur sur une structure cookie
  52. * sortie : d0 = 0 = ok
  53. *               -1 = cookie déjà existant
  54. *               -2 = erreur création impossible
  55. * ------------------------------------------------------------------------
  56.  
  57. add_cookie:
  58.     movem.l    d1-d7/a1-a6,-(a7)
  59.     move.l    a0,pt_cook
  60.     pea        rout_add(pc)
  61.     move.w    #$26,-(a7)
  62.     trap    #14
  63.     addq.l    #6,a7
  64.     move.w    rep,d0
  65.     movem.l    (a7)+,d1-d7/a1-a6
  66.     rts
  67.     
  68. rout_add:
  69.     clr.w    d7                ; nbe de cookies = 0
  70.     move.w    #-2,rep            ; par défaut = erreur
  71.     move.l    pt_cook,a0        ; a0 = pointeur cookie
  72.     move.l    (a0),d0            ; d0 = ident.
  73.     move.l    $5a0.w,a0        ; a0 = adresse jar
  74.     cmp.l    #0,a0            ; inexistant ?
  75.     beq.b    fin_add            ; oui -> sort
  76.  
  77. bcl_add:
  78.     move.l    (a0),d1            ; d1 = id cookie
  79.     beq.b    fin_jar            ; = 0 (fini) -> suite
  80.     cmp.l    d1,d0            ; = cookie a ajouter ?
  81.     beq.b    deja_present    ; oui -> sort
  82.     addq.l    #8,a0            ; passe au suivant
  83.     addq.w    #1,d7            ; nbe cookie + 1
  84.     bra.b    bcl_add            ; boucle
  85.  
  86. fin_jar:
  87.     move.l    4(a0),d6        ; d6 = nombre de slots dispos
  88.     cmp.w    d7,d6            ; slots tous occupés ?
  89.     blt.b    fin_add            ; oui -> sort
  90.     move.l    pt_cook,a1        ; a1 = adresse structure cookie
  91.     move.l    (a1),(a0)+        ; place l'id dans le jar
  92.     move.l    4(a1),(a0)+        ; place les infos
  93.     clr.l    (a0)+            ; efface cookie suivant (final)
  94.     move.l    d6,(a0)            ; nbe de slots
  95.     clr.w    rep                ; ok
  96. fin_add:        
  97.     rts                        ; fin
  98.  
  99. deja_present:
  100.     move.w    #-1,rep            ; déjà là !
  101.     rts
  102.     
  103. * ------------------------------------------------------------------------------
  104. * enleve un cookie
  105. * entrée d0 = identificateur
  106. * sortie d0 = 0 : erreur 1 : ok
  107. * ------------------------------------------------------------------------------
  108.  
  109. remove_cookie:
  110.     movem.l    d1-d7/a0-a6,-(a7)
  111.     move.l    d0,param
  112.     pea        rem_cook(pc)
  113.     move.w    #$26,-(a7)
  114.     trap    #14
  115.     addq.l    #6,a7
  116.     move.w    rep,d0
  117.     movem.l    (a7)+,d1-d7/a0-a6
  118.     rts    
  119.  
  120. rem_cook:
  121.     move.w    #0,rep            ; par défaut : erreur
  122.     move.l    param,d0        ; d0 = identificateur
  123.     move.l    $5a0.w,a0        ; a0 = adresse cookie jar
  124.     cmp.l    #0,a0            ; existant ?
  125.     beq.b    fin_remove        ; oui -> on sort
  126. bc:
  127.     move.l    (a0),d1            ; d1 = identificateur cookie
  128.     beq.b    fin_remove        ; = 0 ? -> donc pas trouvé -> on sort
  129.     cmp.l    d0,d1            ; on compare avec l'id cherché
  130.     beq.b    ok_rem            ; identiques -> on enleve
  131.     addq.l    #8,a0            ; passe au cookie suivant
  132.     bra.b    bc                ; boucle
  133.     
  134. ok_rem:
  135.     lea        8(a0),a1        ; passe au cookie suivant
  136.     move.l    (a1)+,d0        ; d0 = identificateur cookie suivant
  137.     beq.s    fin_rem            ; si = 0 -> dernier cookie
  138.     move.l    d0,(a0)+        ; sinon recopie sur cookie a enlever
  139.     move.l    (a1)+,(a0)+        ; recopie contenu cookie
  140.     bra.b    ok_rem            ; boucle
  141.  
  142. fin_rem:
  143.     move.l    d0,(a0)+        ; recopie cookie final
  144.     move.l    (a1),(a0)        ; d1 = nombre max de cookies
  145.     move.w    #1,rep            ; retour TRUE
  146. fin_remove:
  147.     rts                        ; fin
  148.  
  149.     data
  150.  
  151. rep:        ds.w    1
  152. pt_cook:    ds.l    1
  153. param:        ds.l    1